RPGIV @ Work

A unique site for RPG and System i Lovers

Welcome!

Hi, this site will provide all what you need in System i and RPG developments.

My Name is Chamara Withanachchi, System i Expert and RPG Developer. And in the field for last 11 years.

I hope you will find lot of valuable information from this site

Generate a screen print like "Print-Key"- Function Print E-mail
User Rating: / 0
PoorBest 
Written by Chamara Withanachchi   

     **-- Header specifications:  --------------------------------**
     H BndDir( 'QC2LE' : 'QSNAPI' )  Option( *SrcStmt )
     **-- Global variables:  -------------------------------------**
     D InpBufHdl       s             10i 0
     D InpDtaPtr       s               *
     **-- Parameters:  -------------------------------------------**
     D Parm            Ds
     D Row                           10i 0
     D Col                           10i 0
     D NbrBytRtn                     10i 0
     D Screen                      3564a
     **-- Prototype for DSM API's:  ------------------------------**
     D GetCsrAdr       Pr            10i 0 ExtProc( 'QsnGetCsrAdr' )
     D  Row                          10i 0
     D  Col                          10i 0
     D  LlvEnvHdl                    10i 0 Const  Options( *Omit )
     D  ApiError                   1024a          Options( *Omit: *VarSize )
     **
     D CrtInpBuf       Pr            10i 0 ExtProc( 'QsnCrtInpBuf' )
     D  InpBufSiz                    10i 0 Const
     D  BufIncSiz                    10i 0 Const  Options( *Omit )
     D  BufMaxSiz                    10i 0 Const  Options( *Omit )
     D  InpBufHdl                    10i 0        Options( *Omit )
     D  ApiError                   1024a          Options( *Omit: *VarSize )
     **
     D ReadScr         Pr            10i 0 ExtProc( 'QsnReadScr' )
     D  NbrBytRead                   10i 0        Options( *Omit )
     D  InpBufHdl                    10i 0 Const  Options( *Omit )
     D  CmdBufHdl                    10i 0 Const  Options( *Omit )
     D  LlvEnvHdl                    10i 0        Options( *Omit )
     D  ApiError                   1024a          Options( *Omit: *VarSize )
     **
     D RtvDta          Pr              *   ExtProc( 'QsnRtvDta' )
     D  InpBufHdl                    10i 0 Const
     D  InpDtaPtr                      *          Options( *Omit )
     D  ApiError                   1024a          Options( *Omit: *VarSize )
     **
     D Beep            Pr            10i 0 ExtProc( 'QsnBeep' )
     D  CmdBufHdl                    10i 0 Const  Options( *Omit )
     D  LlvEnvHdl                    10i 0 Const  Options( *Omit )
     D  ApiError                   1024a          Options( *Omit: *VarSize )
     **
     D DltBuf          Pr            10I 0 ExtProc( 'QsnDltBuf' )
     D  BufferHdl                    10I 0 Const
     D  ApiError                   1024a          Options( *Omit: *VarSize )
     **
     D MemCpy          Pr              *   ExtProc( 'memcpy' )
     D pOutMem                         *   Value
     D pInpMem                         *   Value
     D InpMemSiz                     10u 0 Value
     **
     **--Mainline:  ----------------------------------------------**
     **
     C                   Eval      InpBufHdl  =  CrtInpBuf( 27 * 132
     C                                                    : *Omit
     C                                                    : *Omit
     C                                                    : *Omit
     C                                                    : *Omit )
     **
     C                   CallP     GetCsrAdr( Row
     C                                      : Col
     C                                      : *Omit
     C                                      : *Omit )
     **
     C                   Eval      NbrBytRtn  =  ReadScr( *Omit
     C                                                  : InpBufHdl
     C                                                  : *Omit
     C                                                  : *Omit
     C                                                  : *Omit )
     **
     C                   Eval      InpDtaPtr  =  RtvDta( InpBufHdl
     C                                                 : *Omit
     C                                                 : *Omit )
     **
     C                   CallP     MemCpy( %Addr( Screen )
     C                                   : InpDtaPtr
     C                                   : NbrBytRtn  )
     **
     C                   CallP     Beep( *Omit
     C                                 : *Omit
     C                                 : *Omit )
     **
     C                   CallP     DltBuf( InpBufHdl: *Omit )
     **
     C                   Return

Thanks to Carsten Flensburg


User Comments

Please login or register to add comments

<Previous   Next>